Appendix 3. OpenBUGS code for estimating rat tracking rates (probability that at least one rat passes through a baited tracking tunnel in 24 h) in a pine plantation and native forest fragments.

Model
{

	# Priors 
	a ~ dnorm(0, 1.0E-6)				# intercept logit(p), where p = prob of tunnel being tracked
	b.pine ~ dnorm(0, 1.0E-6)			# effect of pine vs native on logit(p)
	b.gr ~ dnorm(0, 1.0E-6)				# effect of grazing on logit(p)
	s.grid ~ dunif(0,100)				# sd among grids in logit(p)
	tau.grid <- pow(s.grid,-2)			# convert to precision
	s.tun ~ dunif(0,100)				# sd among individual tracking tunnel sites
	tau.tun <- pow(s.tun,-2)			# convert to precision
	s.year ~ dunif(0,100)				# sd among years
	tau.year <- pow(s.year,-2)			# convert to precision
	s.time ~ dunif(0,100)				# sd among sampling occasions
	tau.time <- pow(s.time,-2)			# convert to precision

	# Assigning random effects
	for (i in 1:n.grid) {	
		re.grid[i] ~ dnorm(0,tau.grid)		# grid effect on logit(p) 
	}
	for (i in 1:n.tun) {
		re.tun[i] ~ dnorm(0,tau.tun) 		# individual tunnel effect
	}
	for (i in 1:n.time) {
		re.time[i] ~ dnorm(0,tau.time) 		# time effect (sampling occasion)
	}
	for (i in 1:n.year) {
		re.year[i] ~ dnorm(0,tau.year) 		# year effect
	}

	# Sampling tracking data (either rat tracks or mouse tracks)
	for (i in 1:n.obs) {				# for each individual tracking tunnel on each sampling occasion...		
		x[i] ~ dbern(p[i])						# whether tunnel was tracked is sampled from Bernoulli distribution
		logit(p[i]) <- fixed[i]+random[i] # calculate probability of it being tracked
		fixed[i] <- a+b.pine*pine[grid[i]]+b.gr*gr[grid[i]]          
		random[i] <- re.grid[grid[i]]+re.tun[tun[i]]+re.year[year[i]]+re.time[time[i]]
	}

	# Calculating derived parameters
	for (i in 1:n.grid) {	# for each grid, calculate...
		logit(p.grid[i]) <- a+b.pine*pine[i]+b.gr*gr[i]+re.grid[i]	# mean tracking probability 
	}

}